hasanabs/SX128X-LoRa
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

Init fork from Stuart Robinson's repo

Browse Source
This commit is contained in:
Hasan Albinsaid
2024-10-03 14:30:13 +03:00
commit 9395706524
201 changed files with 45709 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

195
examples/SX128x_examples/Reliable/202_Reliable_Receiver/202_Reliable_Receiver.ino Normal file
View File

@ -0,0 +1,195 @@
/*******************************************************************************************************
Programs for Arduino - Copyright of the author Stuart Robinson - 25/09/21
This program is supplied as is, it is up to the user of the program to decide if the program is
suitable for the intended purpose and free from errors.
*******************************************************************************************************/
/*******************************************************************************************************
Program Operation - This is a simple demonstration of the receipt of a 'Reliable' packet.
A reliable packet has 4 bytes automatically appended to the end of the buffer\array that is the data
payload. The first two bytes appended are a 16bit 'NetworkID'. This receiver needs to have the same
NetworkID as configured for the transmitter. The receiver program uses the NetworkID to check that
the received packet is from a known source. The third and fourth bytes appended are a 16 bit CRC of
the payload. This receiver carries out its own CRC check on the received payload and can then verify
this against the CRC appended to the packet. The receiver is thus able to check if the payload is valid.
For a packet to be accepted by the receiver, the networkID and payload CRC appended to the packet by the
transmitter need to match those from the receiver which gives a high level of assurance that the packet
is valid.
The received payload is copied on receive into the RXBUFFER array. This buffer can be set up to a maximum
size of 251 bytes. A LoRa packet can be up to 255 bytes, but the reliable packet uses 4 bytes to hold the
networkID and payload CRC. As an example if the the transmitted payload array is 16 bytes long, then the
transmit function will increase the packet size by 4 to 20 to accommodate the networkID and payload CRC.
Note that any packets arriving with a length greater than the length defined for RXBUFFER + 4 bytes will
be rejected.
It is possible to use the 'NetworkID' to direct the packet to specific receivers.
Serial monitor baud rate should be set at 115200.
*******************************************************************************************************/
#include <SPI.h> //the LoRa device is SPI based so load the SPI library
#include <SX128XLT.h> //include the appropriate library
SX128XLT LT; //create a library class instance called LT
#define NSS 10 //select pin on LoRa device
#define NRESET 9 //reset pin on LoRa device
#define RFBUSY 7 //RFBUSY pin on LoRa device
#define DIO1 3 //DIO1 pin on LoRa device, used for sensing RX and TX done
#define LED1 8 //LED used to indicate transmission
#define LORA_DEVICE DEVICE_SX1280 //we need to define the device we are using
#define RXtimeout 10000 //receive timeout in mS.
const uint8_t RXBUFFER_SIZE = 251; //RX buffer size, set to max payload length of 251, or maximum expected payload length
uint8_t RXBUFFER[RXBUFFER_SIZE]; //create the buffer that received packets are copied into
uint8_t RXPacketL; //stores length of packet received
uint8_t RXPayloadL; //stores length of payload received
uint8_t PacketOK; //set to > 0 if packetOK
int16_t PacketRSSI; //stores RSSI of received packet
uint16_t LocalPayloadCRC; //locally calculated CRC of payload
uint16_t RXPayloadCRC; //CRC of payload received in packet
uint16_t TransmitterNetworkID; //the NetworkID from the transmitted and received packet
const uint16_t NetworkID = 0x3210; //NetworkID identifies this connection, needs to match value in transmitter
void loop()
{
PacketOK = LT.receiveReliable(RXBUFFER, RXBUFFER_SIZE, NetworkID, RXtimeout, WAIT_RX); //wait for a packet to arrive with 60seconds (60000mS) timeout
digitalWrite(LED1, HIGH); //LED on to indicate receive
RXPacketL = LT.readRXPacketL(); //get the received packet length
RXPayloadL = RXPacketL - 4; //payload length is always 4 bytes less than packet length
PacketRSSI = LT.readPacketRSSI(); //read the received packets RSSI value
if (PacketOK > 0)
{
//if the LT.receiveReliable() returns a value > 0 for PacketOK then packet was received OK
packet_is_OK();
}
else
{
//if the LT.receiveReliable() function detects an error PacketOK is 0
packet_is_Error();
}
digitalWrite(LED1, LOW);
Serial.println();
}
void packet_is_OK()
{
Serial.print(F("Payload received OK > "));
LT.printASCIIPacket(RXBUFFER, RXPayloadL);
Serial.println();
if (LT.getReliableConfig(NoReliableCRC))
{
Serial.println(F("Payload CRC check disabled"));
}
printPacketDetails();
Serial.println();
}
void packet_is_Error()
{
uint16_t IRQStatus;
IRQStatus = LT.readIrqStatus(); //read the LoRa device IRQ status register
Serial.print(F("Error "));
if (IRQStatus & IRQ_RX_TIMEOUT) //check for an RX timeout
{
Serial.print(F(" RXTimeout "));
}
else
{
printPacketDetails();
}
}
void printPacketDetails()
{
LocalPayloadCRC = LT.CRCCCITT(RXBUFFER, RXPayloadL, 0xFFFF); //calculate payload crc from the received RXBUFFER
TransmitterNetworkID = LT.getRXNetworkID(RXPacketL);
RXPayloadCRC = LT.getRXPayloadCRC(RXPacketL);
Serial.print(F("LocalNetworkID,0x"));
Serial.print(NetworkID, HEX);
Serial.print(F(",TransmitterNetworkID,0x"));
Serial.print(TransmitterNetworkID, HEX);
Serial.print(F(",LocalPayloadCRC,0x"));
Serial.print(LocalPayloadCRC, HEX);
Serial.print(F(",RXPayloadCRC,0x"));
Serial.print(RXPayloadCRC, HEX);
LT.printReliableStatus();
}
void led_Flash(uint16_t flashes, uint16_t delaymS)
{
uint16_t index;
for (index = 1; index <= flashes; index++)
{
digitalWrite(LED1, HIGH);
delay(delaymS);
digitalWrite(LED1, LOW);
delay(delaymS);
}
}
void setup()
{
Serial.begin(115200);
Serial.println();
Serial.println(F("202_Basic_Reliable_Receiver Starting"));
pinMode(LED1, OUTPUT);
led_Flash(2, 125); //two quick LED flashes to indicate program start
SPI.begin();
if (LT.begin(NSS, NRESET, RFBUSY, DIO1, LORA_DEVICE))
{
Serial.println(F("LoRa Device found"));
delay(1000);
}
else
{
Serial.println(F("No LoRa device responding"));
do
{
digitalWrite(LED1, HIGH);
delay(50);
digitalWrite(LED1, LOW);
delay(50);
} while (1);
}
LT.setupLoRa(2445000000, 0, LORA_SF7, LORA_BW_0400, LORA_CR_4_5);
Serial.println();
LT.printModemSettings(); //reads and prints the configured LoRa settings, useful check
Serial.println();
LT.printOperatingSettings(); //reads and prints the configured operating settings, useful check
Serial.println();
Serial.println();
LT.printRegisters(0x900, 0x9FF); //print contents of device registers, normally 0x00 to 0x4F
Serial.println();
Serial.println(F("Receiver ready"));
Serial.println();
//enable the following line if you want to disable payload CRC checking
//LT.setReliableConfig(NoReliableCRC); //disable payload CRC check
}